**MPLUS SYNTAX FOR THE COMBINED LST MODEL**

Title: Combined LST

DATA: File is LST.dat;

TYPE IS individual;

Variable: NAMES ARE

ID K11\_SEX

Y1T1\_C Y2T1\_C Y3T1\_C

Y1T2\_C Y2T2\_C Y3T2\_C

Y1T3\_C Y2T3\_C Y3T3\_C

Y1T1\_T Y2T1\_T Y3T1\_T

Y1T2\_T Y2T2\_T Y3T2\_T

Y1T3\_T Y2T3\_T Y3T3\_T;

MISSING are all (999);

USEvariables are

Y1T1\_C Y2T1\_C Y3T1\_C

Y1T2\_C Y2T2\_C Y3T2\_C

Y1T3\_C Y2T3\_C Y3T3\_C

Y1T1\_T Y2T1\_T Y3T1\_T

Y1T2\_T Y2T2\_T Y3T2\_T

Y1T3\_T Y2T3\_T Y3T3\_T;

!!! Y1 FEEL SORRY FOR OTHERS

!!! Y2 FELL SORRY FOR OTHER CHILDREN TEASED

!!! Y3 FELL SORRY FOR OTHER CHILDREN SAD OR UPSET

!!! C = CAREGIVERS T = TEACHERS

Analysis:

Estimator = MLR;

Model:

!!!!!!!!!!!!!!!!!!!!SYMPATHY CAREGIVERS (parents) !!!!!!!!!!!!

!!!OCCASION SPECIFIC LATENT FACTORS (ZETA)

SYP\_T1 BY Y1T1\_C@1;

SYP\_T1 BY Y2T1\_C (G2);

SYP\_T1 BY Y3T1\_C (G3);

SYP\_T2 BY Y1T2\_C@1;

SYP\_T2 BY Y2T2\_C (G2);

SYP\_T2 BY Y3T2\_C (G3);

SYP\_T3 BY Y1T3\_C@1;

SYP\_T3 BY Y2T3\_C (G2);

SYP\_T3 BY Y3T3\_C (G3);

!!!!!INTERCEPTS!!!!

[Y1T1\_C@0];

[Y2T1\_C] (t2);

[Y3T1\_C] (pt33); !!!!different intercept!!!

[Y1T2\_C@0];

[Y2T2\_C] (t2);

[Y3T2\_C] (t3);

[Y1T3\_C@0];

[Y2T3\_C] (t2);

[Y3T3\_C] (t3);

!!!!!!!VARIABILITY OF STATE FACTORS!!!!!

SYP\_T1 (state1);

SYP\_T2 (state1);

SYP\_T3 (state1);

!!!!!!TRAIT FACTOR!!!!

KSIP BY Y1T1\_C@1

Y2T1\_C (L2)

Y3T1\_C (pL33) !!! different factor loading

Y1T2\_C@1

Y2T2\_C (L2)

Y3T2\_C (L3)

Y1T3\_C@1

Y2T3\_C (L2)

Y3T3\_C (L3);

[KSIP]; !!!latent mean of the latent trait factor KSIP!!!

KSIP (varP); !!!variance of the latent trait factor KSIP!!!

!!!!! CORRELATIONS AMONG LATENT STATE AND TRAIT FACTORS FIXED TO BE ZERO!!!!!

SYP\_T1 WITH SYP\_T2@0 SYP\_T3@0;

SYP\_T2 WITH SYP\_T3@0;

KSIP WITH SYP\_T1@0 SYP\_T2@0 SYP\_T3@0;

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!SYMPATHY TEACHER!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!!!!OCCASION SPECIFIC FACTORS (ZETA)!!!!!

SYMT\_T1 BY Y1T1\_T@1 ;

SYMT\_T1 BY Y2T1\_T (G2);

SYMT\_T1 BY Y3T1\_T (G3);

SYMT\_T2 BY Y1T2\_T@1;

SYMT\_T2 BY Y2T2\_T (G2);

SYMT\_T2 BY Y3T2\_T (G3);

SYMT\_T3 BY Y1T3\_T@1;

SYMT\_T3 BY Y2T3\_T (G2);

SYMT\_T3 BY Y3T3\_T (G3);

[Y1T1\_T@0];

[Y2T1\_T] (t2) ;

[Y3T1\_T] (t3);

[Y1T2\_T@0];

[Y2T2\_T] (t2);

[Y3T2\_T] (t3);

[Y1T3\_T@0];

[Y2T3\_T] (t2);

[Y3T3\_T] (t3);

!!!!!!!!VARIABILITY OF STATE FACTORS!!!!!

SYMT\_T1 (state2);

SYMT\_T2 (state2);

SYMT\_T3 (state2);

!!!!!!!!!LATENT TRAIT FACTOR KSIT!!!!!!

KSIT BY Y1T1\_T@1

Y2T1\_T (L2)

Y3T1\_T (L3)

Y1T2\_T@1

Y2T2\_T (L2)

Y3T2\_T (L3)

Y1T3\_T@1

Y2T3\_T (L2)

Y3T3\_T (L3);

[KSIT]; !!!LATENT MEAN OF THE TRAIT FACTOR KSIT!!!

KSIT (varT); !!!! VARIANCE OF THE TRAIT FACTOR KSIT!!!

!!!!!!!!!!INDEXES OF CROSS-INFORMANT CONSISTENCY AT THE STATE LEVEL!!!!!!!

SYP\_T1 WITH SYMT\_T1 (r1);

SYP\_T2 WITH SYMT\_T2 (r1);

SYP\_T3 WITH SYMT\_T3 (r1);

!!!!!!!!!!INDEX OF CROSS-INFORMANT CONSISTENCY AT THE TRAIT LEVEL!!!!!!!

KSIP with KSIT;

!!!!!!! CORRELATIONS AMONG LATENT STATE AND TRAIT FACTORS FIXED TO BE ZERO!!!!!!

SYMT\_T1 WITH SYMT\_T2@0 SYMT\_T3@0;

SYMT\_T2 WITH SYMT\_T3@0;

KSIT WITH SYMT\_T1@0 SYMT\_T2@0 SYMT\_T3@0;

!CORR AMONG LATENT STATE AND TRAIT FACTORS FIXED TO BE ZERO ACROSS INFORMANTS!!!!!!

SYP\_T1 WITH SYMT\_T2@0 SYMT\_T3@0;

SYP\_T2 WITH SYMT\_T1@0 SYMT\_T3@0;

SYP\_T3 WITH SYMT\_T1@0 SYMT\_T2@0;

KSIP WITH SYMT\_T1@0 SYMT\_T2@0 SYMT\_T3@0;

KSIT WITH SYP\_T1@0 SYP\_T2@0 SYP\_T3@0;

output:

sampstat standardized modindices (3.84) cinterval residual tech1 tech4;